Home » excel » excel – Look up formula works well except for one column

# excel – Look up formula works well except for one column

Questions:

I have an excel file that has been uploaded here

``````http://www58.zippyshare.com/v/99974349/file.html
``````

The formula works great except for a column with descending values.

``````=INDEX(
INDIRECT("'"&LOOKUP(B5,TblA)&"'!A6:A36"),
LOOKUP(9.99999999999999E+307,
SEARCH("-"&C8&"-","-"&INDIRECT("'"&LOOKUP(B5,TblA)&"'!C6:C36")&"-"),
ROW(C6:C36)-ROW(C6)+1))
``````

Let me explain the excel file.

I have one main sheet ‘Report’ and 4 other sheets correspond to 4 age groups. – 4.2.0 to 4.7.30, 4.8.0 to 5.1.30, 5.2.0 to 5.7.30 and 5.8.0 to 6.1.30. Depending on the Age (B5) in the sheet ‘Report’, I select one of the 4 sheet to pick values from. I pick the correct sheet using a Table Name TblA which contains all sheet names and is defined from A24 to B27 in the sheet ‘Report’.

In the sample sheet that is uploaded, B5 contains the value 5.7 which means we have to select the sheet 5.2.0 to 5.7.30.

Now from the sheet 5.2.0 to 5.7.30, I have to seek the respective Standard Score (1st column) for every Raw Score entered in ‘Report’.

Here are the steps:

A. Enter Raw scores in sheet ‘Report’ C7 to C15

B. Search Respective sheet depending on age (B5 cell), in our case 5.2.0 to 5.7.30 since age is 5.7

C. Populate Standard score from Raw scores by picking the corresponding column in the 4 sheets. For example, if Raw Score of Col1 is 25 (C7), then pick the Standard score of Col1 from 5.2.0 to 5.7.30 and enter in D7 and so on.

D. This way all standard scores are filled in D7 to D15.

The formula works great except for D13 in sheet ‘Report’ since if you observe ColD in 5.2.0 to 5.7.30, it is in descending order.

How do I change the formula to accomodate this unique column?

Well, it’s not really the order that’s causing the error, it’s because you don’t have any results! The formula you use is trying to find `-159-` which it cannot find at all in the age sheet. You really need something to look into ranges, so that if you have 159, it will return a positive result when you try to match against `139-160`.

I have made a formula building it from smaller ones, but when assembled, the repeating units make it daunting… Also, it’s an array formula, so you need to use Ctrl+Shift+Enter for it to work as intended. You can still drag the formula down.

``````=INDEX(
INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!A6:A36"),
IFERROR(
MATCH(
C7,
INDEX(
INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B6:J36"),
0,
MATCH(B7,INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B5:J5"),0)
)*1,
0
),
MATCH(
1,
IF(
1*LEFT(
INDEX(
INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B6:J36"),
0,
MATCH(B7,INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B5:J5"),0)
),
FIND(
"-",
INDEX(
INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B6:J36"),
0,
MATCH(B7,INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B5:J5"),0)
)
)-1
)<=C7,
1,
0
)*
IF(
1*MID(
INDEX(
INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B6:J36"),
0,
MATCH(B7,INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B5:J5"),0)
),
FIND(
"-",
INDEX(
INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B6:J36"),
0,
MATCH(B7,INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B5:J5"),0)
)
)+1,
100
)>=C7,
1,
0
)
,0
)
)
)
``````

The single line version…

``````=INDEX(INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!A6:A36"),IFERROR(MATCH(C7,INDEX(INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B6:J36"),0,MATCH(B7,INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B5:J5"),0))*1,0),MATCH(1,IF(1*LEFT(INDEX(INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B6:J36"),0,MATCH(B7,INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B5:J5"),0)),FIND("-",INDEX(INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B6:J36"),0,MATCH(B7,INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B5:J5"),0)))-1)<=C7,1,0)*IF(1*MID(INDEX(INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B6:J36"),0,MATCH(B7,INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B5:J5"),0)),FIND("-",INDEX(INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B6:J36"),0,MATCH(B7,INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B5:J5"),0)))+1,100)>=C7,1,0),0)))
``````

You can notice that there are some repeating blocks, namely:

``````INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B6:J36")
``````

For the sheet name;

``````INDEX(
INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B6:J36"),
0,
MATCH(B7,INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B5:J5"),0)
)
``````

Which is a larger block to make the formula a bit more flexible (it automatically picks the correct column e.g. if you change B8 `Exclusion` to `Col1`, the formula will automatically adjust itself)

If I call the first `Sheet` and the second `Column`, it becomes much shorter and perhaps easier to understand:

``````=INDEX(
Sheet,
IFERROR(
MATCH(
C7,
Column*1,
0
),
MATCH(
1,
IF(
1*LEFT(
Column,
FIND(
"-",
Column
)-1
)<=C7,
1,
0
)*
IF(
1*MID(
Column,
FIND(
"-",
Column
)+1,
100
)>=C7,
1,
0
)
,0
)
)
)
``````

Or

``````=INDEX(Sheet,IFERROR(MATCH(C7,Column*1,0),MATCH(1,IF(1*LEFT(Column,FIND("-",Column)-1)<=C7,1,0)*IF(1*MID(Column,FIND("-",Column)+1,100)>=C7,1,0),0)))
``````

Disclaimer: I’m not sure if there are any way to make this even shorter, but I guess that as long as it’s working right now ^^

Explanation:

As I mentioned before, the formula is based off several smaller ones and quite a few repeats of those.

``````INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B6:J36")
``````

As you already know (it’s a variation of a part of your own formula), this gives the area containing all the different ages. Using it and the below, we get this:

``````INDEX(
INDIRECT('"&LOOKUP(\$B\$5,TblA)&"'!B6:J36"),
0,
MATCH(B7,INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B5:J5"),0)
)
``````

Into:

``````INDEX(
'Sheet'!B6:J36,
0,
MATCH(B7,'Sheet'!B5:J5,0)
)
``````

Index will thus look into the range `'Sheet'!B6:J36`, `0` indicates it will take any column(s) and `MATCH(B7,'Sheet'!B5:J5,0)` returns the nth column by taking the value of `B7` (in the case of your spreadsheet, `Col1`) and looking it into `'Sheet'!B5:J5` which gives `1`. The above will thus return the range `'Sheet'!B6:B36`. Let’s put it in the formula:

``````=INDEX(
'Sheet'!A6:A36,
IFERROR(
MATCH(
C7,
'Sheet'!B6:B36*1,
0
),
MATCH(
1,
IF(
1*LEFT(
'Sheet'!B6:B36,
FIND(
"-",
'Sheet'!B6:B36
)-1
)<=C7,
1,
0
)*
IF(
1*MID(
'Sheet'!B6:B36,
FIND(
"-",
'Sheet'!B6:B36
)+1,
100
)>=C7,
1,
0
)
,0
)
)
)
``````

This formula is itself a giant `INDEX` formula, with range `'Sheet'!A6:A36` and row number as the big `IFERROR` group. The first part of the `IFERROR()` gets evaluated first:

``````MATCH(
C7,
'Sheet'!B6:B36*1,
0
)
``````

This should be easy enough to understand. It looks for the raw score (from `C7`) into the range we obtained earlier, times 1 to convert everything to number (you can’t look up numbers and text and expect a match). So that if there’s an exact match of a number, it will return the row number of the found raw score and feed it to the `INDEX()`. For example, if the first row is returned, we get:

``````=INDEX('Sheet'!A6:A36,1)
``````

Which is `'Sheet'!B6`. If however there’s no match (i.e. the raw score cannot be found), `MATCH` will return an error. And that’s when the second part of the `IFERROR` comes into play:

``````MATCH(
1,
IF(
1*LEFT(
'Sheet'!B6:B36,
FIND(
"-",
'Sheet'!B6:B36
)-1
)<=C7,
1,
0
)*
IF(
1*MID(
'Sheet'!B6:B36,
FIND(
"-",
'Sheet'!B6:B36
)+1,
100
)>=C7,
1,
0
)
,0
)
``````

This `MATCH` tries to find `1` within what seems to be two `IF`s; the first one being:

``````IF( 1*LEFT('Sheet'!B6:B36,FIND("-",'Sheet'!B6:B36)-1)<=C7 , 1 , 0)
``````

`FIND("-",'Sheet'!B6:B36)-1` gets the position of the last character before the `-` in the column `'Sheet'!B6:B36`.

With those values, this `FIND` would return:

``````12-13       -> 2
145-155     -> 3
1567-1865   -> 4
``````

The `IF` thus becomes:

``````IF( 1*LEFT('Sheet'!B6:B36,{2,3,4})<=C7 , 1 , 0)
``````

Notice the braces here; they indicate an array and that’s why this is an array formula. `LEFT` then extracts all the characters before the `-` (remember your other question, I answered with a technique very similar to this):

``````12-13       -> 2  ->  12
145-155     -> 3  ->  145
1567-1865   -> 4  ->  1567
``````

Which is…

``````IF( 1*{12,145,1567}<=C7 , 1 , 0)
``````

Again, `1*` converts those to actual numbers because `LEFT` be default returns text characters. It’s important here to do this because we’re going to use the comparator `<=`, so that if the value to the left of `C7` (the raw score), then the IF should return `1`, else, it should return `0`. Let’s say that the raw score was `154`. The results would be:

``````IF( {12,145,1567}<=154 , 1 , 0)
IF( {TRUE,TRUE,FALSE} , 1 , 0)
{1,1,0}
``````

I just realised that the formula can be made a little shorter xD Anyway, we’ll see that later. The next `IF` behaves in a similar fashion, but checks for the value at the right of the `-`:

``````IF( 1*MID('Sheet'!B6:B36,FIND("-",'Sheet'!B6:B36)+1,100)>=C7 , 1 , 0)
``````

With…
FIND MID(‘Sheet’!B6:B36, X, 100)
12-13 -> 4 -> 13
145-155 -> 5 -> 155
1567-1865 -> 6 -> 1865

You can notice that this formula will stop working if you have something above 100 character long here. Anyway, the `IF` thus becomes:

``````IF( {13,155,1865}>=154 , 1 , 0)
IF( {FALSE,TRUE,TRUE} , 1 , 0)
{0,1,1}
``````

Now that we have these, the `MATCH` from before becomes:

``````MATCH( 1 , {1,1,0}*{0,1,1} , 0)
``````

Some simple math makes this into:

``````MATCH( 1 , {0,1,0} , 0)
``````

And what is the position of the `1` in there? That’s right, position 2!

Our original formula this becomes:

``````=INDEX( 'Sheet'!A6:A36 , IFERROR( #Error! , 2 ) )
``````

So that if nothing was found at first, it will return an error (`#N/A` in this case) and instead return `2`. `=INDEX( 'Sheet'!A6:A36 , 2 )` gives `'Sheet'!A7`.

And the slightly shorter version is:

``````=INDEX(INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!A6:A36"),IFERROR(MATCH(C7,INDEX(INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B6:J36"),0,MATCH(B7,INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B5:J5"),0))*1,0),MATCH(1,(1*LEFT(INDEX(INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B6:J36"),0,MATCH(B7,INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B5:J5"),0)),FIND("-",INDEX(INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B6:J36"),0,MATCH(B7,INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B5:J5"),0)))-1)<=C7)*(1*MID(INDEX(INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B6:J36"),0,MATCH(B7,INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B5:J5"),0)),FIND("-",INDEX(INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B6:J36"),0,MATCH(B7,INDIRECT("'"&LOOKUP(\$B\$5,TblA)&"'!B5:J5"),0)))+1,100)>=C7),0)))
``````

I actually removed the inner `IF`s, because `(a>b)*(c>b)` already returns 0s and 1s since `TRUE` multiplied by `TRUE` gives `1` in excel.

In Excel 2007 the formulae are returning a lot of circular reference warnings, so it may be worth adding a tag for your Excel version. Mine is Excel 2007 but with it the results you want seem achievable as below:

1. To shorten the formulae and reduce computation I have added in Report C5 “Table” and in D5 `=VLOOKUP(B5,TblA,2,1)`.
2. I have also inserted a column immediately to the right of ColumnH (“ColD”) in 5.2.0 to 5.7.30 and applied Text To Columns on Column H, with `-` as the delimiter.
3. I then applied to Report E7 and copied down to E15:

`=INDEX(INDIRECT("'"&D\$5&"'!A6:A36"),MATCH(C7,INDIRECT("'"&D\$5&"'!"&CHAR(ROW()+59)&"6:"&CHAR(ROW()+59)&"36"),0))`

and adjusted the `59`s to `60`s in the last three rows. Such adjustment would not be necessary if ColumnI were moved far enough to the right.

4. In E13 I changed the match from exact to next higher (final `0` to `-1`).

5. For Figures I cheated and changed K23 in 5.2.0 to 5.7.30 to 22 from 21-22, but such banding could, for other columns, be treated in much the same way as I did for ColD.