Home » excel » Finding the value in excel or vba

Finding the value in excel or vba

Posted by: admin May 14, 2020 Leave a comment

   Column A    Column B
  13-06-2013    10:50
  13-06-2013    11:30
  13-06-2013    12:40
  14-06-2013    10:30

I need to find the values which are before a particular entry date and time.

For example, say I want to find the values in the example table above that are immediately prior to the values “13-06-2013” and “12:30”.

Since 12:30 is not in column B, how do I find the values I am looking for? The answer should be 13-06-2013 and 11:30.

How to&Answers:

Here A1 = B1&C1

    A                          B               C

 1  414380.451388888888889   13-06-2013      10:50
 2  414380.479166666666667   13-06-2013      11:30
 3  414380.527777777777778   13-06-2013      12:40
 4  414390.4375              14-06-2013      10:30
 6  Enter date               Enter Time      Returned Time 
 7  13-06-2013                12:30          11:30:00

Setting ‘range_lookup’ as ‘True’ adds the flexibility to return the closest approximate value if the exact value is not available.


I think you’re looking for something like this. using index and match.

I didn’t take into account the date for now. but this gives you an example.

enter image description here


You can compare date strings with operators like > or < etc. Concatenate your values in columns A & B, compare to the desired date/time string. In cell C1 put the following formula, and then drag down:

="13-06-2013 12:30"<A1&" "&B1

or more specifically, depending on which “12:30” you want (AM or PM), ="13-06-2013 12:30AM" or ="13-06-2013 12:30PM"


Your data in column B may default to AM unless otherwise specified/imported differently, so you may need to tweak the data or to account for this.


Here is another approach to answering your question that uses a combination of MATCH, INDEX, and array operations to provide a compact formula solution that does not rely on helper columns.

I’ll assume that your two columns of dates and times are in cells A2:B5, and the two date and time values that you want to look up are in cells A9:A10. Then the following two formulas will return what you require, the latest date and time values in your data that are less than or equal to the date and time that you are looking up. (The dollar signs in the formulas are hard on the eyes, but they are important if you will need to copy the formulas to other locations; for clarity, I omit them in the discussion that follows.)

  DATE: =INDEX($A$2:$B$5,MATCH(A9+A10,$A$2:$A$5+$B$2:$B$5,1),1)  --> 13-06-2013
  TIME: =INDEX($A$2:$B$5,MATCH(A9+A10,$A$2:$A$5+$B$2:$B$5,1),2)  -->   11:30 AM

These are array formulas and need to be entered with the ControlShiftEnter key combination. (Of course, only the bits starting with the equal (=) sign and ending with the last parenthesis need to be entered into the worksheet.)

Things to consider:

  • The formulas assume that your data are valid Excel date and time values. Excel date values are whole numbers that count the number of days that have elapsed since January 1, 1900; Excel time values are decimal amounts between 0 and 1 that represent the fraction of 24 hours that a particular time represents. While your example data don’t display AM or PM, I assume that their underlying values do have that information.

  • If your values are text (having been imported from another source, for instance), you should convert them to date/time values, if lucky, using only Excel’s DATEVALUE and TIMEVALUE functions; if not so lucky, using some combination of Excel’s string manipulation functions as well. (The values could be kept as strings, but you would almost certainly need to massage them so they would compare correctly “alphabetically” – much easier just to deal with Excel date/time values.)

  • If they are not already, your dates and times will need to be sorted from smallest to largest. (Your sample looks like they are sorted, and the formulas assume as much.)

Example worksheet with formulas and results

How the formulas work

The basic idea behind the formulas is two-fold: first find the row in your data that holds the latest (largest) date and time that is still less than or equal to the date and time you are looking up. That row information can then be used to fetch the final result from each column of the data range (one for date and one for time).

Since both date and time figure in to what point in time is latest, the date and time components of both the value to be looked up and the values that will be searched must be combined somehow.

This can be achieved by simply adding the dates and times together. This does nothing more than what Excel does: an Excel date/time value has an integer part (the number of days since 1/1/1900) and a decimal part (the fraction of 24 hours that a particular time represents).

What is neat here is that the adding up of the dates and times – and the lookup of the particular date and time – can be done all at once, on the fly.

Take a look at the MATCH: The cells that contain the date and time to be looked up – A9 and A10 – are added together, and then this sum is matched against the sum of the date column (A2:A5) and the time column (B2:B5) – an operation that is possible of Excel’s array arithmetic capabilities. The match returns a value of 2, indicating correctly that the date and time that fill your requirements are in row 2 of the data table.

     DATE/TIME MATCH:   = MATCH( A9+A10, A2:A5 + B2:B5, 1 )  --> 2

The 1 that is the final argument to the MATCH function is an instruction that the match results be calculated to be less than or equal to the value to be looked. It is the default value and is often omitted, or replaced with another value (for example, using a value of 0 will produce an exact match, if there is one).

(For readability, I’ve removed the dollar signs that are in the full formula; these anchor a range so that it remains the same even if the formula is copied to another location.)

Having figured out the row to look in, the rest of the formula is straightforward. The INDEX function returns the value in a data range that is at the intersection of a specified row and column. So, for the date in question, the formula reduces to:

     DATE FETCH:        = INDEX( A2:B5, 2, 1) --> 13-06-2013

In other words, INDEX is to return the value in the second row and first column of the data range A2:B5.

The formula for the time proceeds in exactly the same fashion, with the only difference that the value is returned from the second column of the data range.